Apple TV용 iTunes에서 사진 자동 새로 고침

Q: 저는 지난주에 Apple TV에서 사진 앨범 새로 고침에 관한 당신의 기사를 찾았고, 저도 비슷한 상황입니다. 저는 Mac 사용자이지만, iPhoto를 거치지 않고도 새로운 사진을 빠르게 추가할 수 있도록 Apple TV에 폴더를 사용하는 것을 선호합니다. 또한, 저는 항상 iMac과 iTunes를 켜두고 있는데, 당신의 기사에서 알게 된 바에 따르면 이것이 새로운 사진이 나타나지 않는 이유인 것 같습니다. AppleScript를 통해 사진을 자동으로 새로 고칠 수 있는 방법이 있을까요? 사진 폴더에 무언가를 추가할 때마다 공유 설정을 건드리는 것보다 더 쉬운 방법이 있으면 좋겠습니다. iTunes를 정기적으로 자동으로 재시작하는 방법에 대한 몇 가지 팁을 보았지만, 저는 자주 새로운 것을 다운로드하거나 Apple TV를 사용하여 iTunes에서 무언가를 시청하거나 듣기 때문에 그렇게 하고 싶지 않습니다.

– 패트릭

A: 실제로 AppleScript를 통해 가능합니다. 약간 번거롭긴 하지만, 기본적으로 사용자의 대신 일반 iTunes 옵션을 선택하는 “GUI 스크립팅”이라는 기능을 사용하기 때문입니다. 하지만 작업은 완료됩니다.

불행히도, iTunes의 사진 공유 기능은 AppleScript에 직접 노출되지 않기 때문에, 우리는 iTunes 컨트롤을 직접 조작해야 합니다. AppleScript가 당신을 대신하여 이를 수행할 수 있도록 하려면, 먼저 OS X 시스템 환경설정 애플리케이션으로 들어가서 유니버설 액세스 설정 아래의 보조 장치에 대한 접근 허용 옵션을 선택해야 합니다.

이 옵션은 AppleScript가 Mac의 애플리케이션에서 사용자 인터페이스 요소에 직접 접근할 수 있도록 허용합니다. 이 작업을 완료한 후, 다음과 같은 AppleScript를 사용하여 iTunes에서 사진 폴더를 새로 고칠 수 있습니다. 이는 공유할 사진 선택 대화 상자를 열고, 몇 가지 옵션을 변경한 다음 그 창을 닫는 단계를 거칩니다.

tell application "System Events"
    if my appIsRunning("iTunes") then
        tell process "iTunes"
            # "고급" 메뉴에서 사진 공유 설정 열기
            click menu item "Choose Photos to Share…" of menu ¬
                "Advanced" of menu bar item "Advanced" of menu bar 1
            
            # "비디오 포함" 체크박스의 상태를 전환하여 변경 강제
            click checkbox "Include videos" of scroll area 1 of window "Photo Sharing Preferences"
            click button "Apply" of window "Photo Sharing Preferences"
            
            # 원래 설정으로 되돌리기 위해 "비디오 포함" 체크박스의 상태를 다시 전환
            click checkbox "Include videos" of scroll area 1 of window "Photo Sharing Preferences"
            click button "Apply" of window "Photo Sharing Preferences"
            
            # 사진 공유 설정 창 닫기
            click (first button of window "Photo Sharing Preferences" whose subrole is "AXCloseButton")
        end tell
    end if
end tell

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

위 스크립트의 인라인 주석은 그 기능을 설명합니다. 요약하자면, 우리는 iTunes가 실행 중인지 확인하고, 그렇다면 단순히 비디오 포함 옵션을 전환하여 iTunes가 사진 컬렉션을 다시 읽도록 강제합니다. 비디오 포함 옵션은 창을 닫기 전에 원래 설정으로 되돌리기 위해 두 번째로 전환됩니다. 일반적으로 사진 폴더에 비디오를 포함하지 않는 경우, 이 두 번째 섹션은 제거할 수 있습니다. 왜냐하면 비디오 포함 옵션이 설정되어 있는지 여부는 중요하지 않기 때문입니다.

이 경우 iTunes가 실행 중이지 않으면 스크립트는 아무 작업도 수행하지 않습니다. 왜냐하면 iTunes를 시작하면 어차피 사진 폴더가 새로 고쳐지기 때문에 스크립트의 나머지 부분이 불필요해지기 때문입니다.

스크립트를 사용하려면, 수동으로 실행하도록 선택할 수 있으며, AppleScript 편집기에서 “응용 프로그램”으로 저장한 후, 편리한 곳—예를 들어 바탕화면이나 Dock에—에 두고 클릭하여 실행할 수 있습니다.

또는 스크립트를 정기적으로 실행되도록 설정하거나 사진 폴더 중 하나에 변경이 있을 때마다 트리거되는 폴더 작업으로 설정할 수 있습니다.

스크립트를 정기적으로 실행되도록 설정하는 것은 타사 유틸리티인 Lingon($3)을 사용하면 가장 쉽고 투명하게 할 수 있지만, “스크립트 실행” 알림 유형으로 반복 iCal 이벤트로 예약하는 것도 가능합니다.

또 다른 접근 방법은 스크립트를 사진에 일반적으로 사용하는 폴더에 대한 폴더 작업으로 실행되도록 설정하는 것입니다. 이를 위해서는 위의 AppleScript에 적절한 폴더 작업 핸들러를 추가하는 아주 약간의 수정이 필요합니다. 다음과 같이:

스크립트 상단에 추가…

on adding folder items to this_folder after receiving added_items
    
    tell application "System Events"
        if my appIsRunning("iTunes") then
            tell process "iTunes"  
            …
            …

…그리고 하단에 삽입:

    …
    …
    end tell
end adding folder items to

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

그런 다음 스크립트를 ~/Library/Scripts/Folder Action Scripts 폴더에 저장해야 하며, Finder에서 폴더를 마우스 오른쪽 버튼으로 클릭하고 서비스, 폴더 작업 설정…을 선택하여 적절한 폴더와 스크립트를 연결할 수 있어야 합니다.

폴더 작업은 기본적으로 하위 폴더를 포함하지 않으므로, 정기적으로 사진을 추가할 계획인 각 폴더와 스크립트를 연결해야 합니다. 또한, 위의 스크립트 수정은 사진 폴더에 새로운 항목을 추가할 때만 시작됩니다. 항목을 제거할 때도 스크립트가 실행되도록 하려면, on removing folder items from this_folder after losing removed_items 핸들러가 있는 메인 코드 블록의 또 다른 복사본을 추가해야 합니다. 이는 독자의 연습으로 남겨두거나, 폴더 작업으로 사용할 준비가 된 스크립트의 전체 버전을 다운로드할 수 있습니다.