Automatisches Aktualisieren von Fotos in iTunes für Apple TV

Q: Ich habe letzte Woche Ihren Artikel über das Aktualisieren von Fotoalben auf dem Apple TV gefunden und befinde mich in einer ähnlichen Situation. Ich bin Mac-Benutzer, bevorzuge es jedoch, Ordner für meinen Apple TV zu verwenden, da ich neue Bilder schnell hinzufügen möchte, ohne iPhoto durchlaufen zu müssen. Ich lasse auch meinen iMac und iTunes ständig eingeschaltet, was ich aus Ihrem Artikel entnehme, der Grund ist, warum ich keine neuen Fotos sehe. Gibt es eine Möglichkeit, meine Fotos automatisch über AppleScript zu aktualisieren oder etwas, das einfacher wäre, als die Freigabeeinstellungen zu ändern, wann immer ich etwas zu meinen Fotofoldern hinzufüge? Ich habe einige Tipps gesehen, wie man iTunes so einrichtet, dass es automatisch nach einem Zeitplan neu startet, aber das möchte ich nicht, da ich oft neue Inhalte herunterlade oder den Apple TV benutze, um etwas aus iTunes zu schauen oder zu hören.

– Patrick

A: Das ist tatsächlich über AppleScript möglich; es ist ein wenig umständlich, da es eine Funktion namens “GUI-Scripting” verwendet, die im Grunde die normalen iTunes-Optionen in Ihrem Namen auswählt, aber es erledigt die Aufgabe.

Leider sind keine der Foto-Freigabefunktionen in iTunes direkt für AppleScript zugänglich, sodass wir gezwungen sind, die iTunes-Steuerelemente direkt zu manipulieren. Um AppleScript dies in Ihrem Namen zu ermöglichen, ist es zunächst notwendig, in Ihre OS X Systemeinstellungen zu gehen und die Option Zugriff für unterstützende Geräte aktivieren unter Ihren Bedienungshilfen-Einstellungen auszuwählen.

Die Option ermöglicht es AppleScript, direkt auf Benutzeroberflächenelemente in Anwendungen auf Ihrem Mac zuzugreifen. Sobald Sie dies getan haben, kann ein AppleScript wie das folgende verwendet werden, um Ihre Fotofolder in iTunes einfach zu aktualisieren, indem die Schritte zum Öffnen des Dialogs Fotos zum Teilen auswählen, Ändern einiger Optionen und anschließendes Schließen dieses Fensters durchlaufen werden.

tell application "System Events"
    if my appIsRunning("iTunes") then
        tell process "iTunes"
            # Öffnen Sie die Foto-Freigabeeinstellungen aus dem Menü "Erweitert"
            click menu item "Choose Photos to Share…" of menu ¬
                "Advanced" of menu bar item "Advanced" of menu bar 1
            
            # Ändern Sie den Status des Kontrollkästchens "Videos einbeziehen", um eine Änderung zu erzwingen
            click checkbox "Include videos" of scroll area 1 of window "Photo Sharing Preferences"
            click button "Apply" of window "Photo Sharing Preferences"
            
            # Ändern Sie den Status des Kontrollkästchens "Videos einbeziehen" erneut, um es auf die ursprüngliche Einstellung zurückzusetzen
            click checkbox "Include videos" of scroll area 1 of window "Photo Sharing Preferences"
            click button "Apply" of window "Photo Sharing Preferences"
            
            # Schließen Sie das Fenster der Foto-Freigabeeinstellungen
            click (first button of window "Photo Sharing Preferences" whose subrole is "AXCloseButton")
        end tell
    end if
end tell

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

Die Inline-Kommentare im obigen Skript beschreiben, was es tut. Zusammenfassend bestätigen wir, dass iTunes läuft, und wenn ja, schalten wir einfach die Option Videos einbeziehen um, um iTunes zu zwingen, die Fotosammlung erneut zu lesen. Die Option Videos einbeziehen wird ein zweites Mal umgeschaltet, um sie auf die ursprüngliche Einstellung zurückzusetzen, bevor das Fenster geschlossen wird. Beachten Sie, dass Sie diesen zweiten Abschnitt entfernen können, wenn Sie normalerweise keine Videos in Ihren Fotofoldern einfügen, da es keine Rolle spielt, ob die Option Videos einbeziehen gesetzt ist oder nicht.

Wenn iTunes in diesem Fall nicht läuft, tut das Skript nichts, da das Starten von iTunes ohnehin die Fotofolder aktualisieren würde, wodurch der Rest des Skripts überflüssig wird.

Um das Skript zu verwenden, können Sie es einfach manuell ausführen, indem Sie es im AppleScript-Editor als “Anwendung” speichern, die Sie dann an einem praktischen Ort ablegen können – wie auf Ihrem Desktop oder in Ihrem Dock – und einfach durch Klicken darauf ausführen.

Alternativ könnten Sie das Skript so einrichten, dass es entweder nach einem Zeitplan oder als Ordneraktion ausgeführt wird, die ausgelöst wird, wann immer Sie eine Änderung an einem Ihrer Fotofolder vornehmen.

Das Einrichten Ihres Skripts zur Ausführung nach einem Zeitplan erfolgt am einfachsten und transparentesten mit dem Drittanbieter-Tool Lingon (3 $), es ist jedoch auch möglich, es als wiederkehrendes iCal-Ereignis mit einem Alarmtyp “Skript ausführen” zu planen.

Eine weitere Möglichkeit, dies anzugehen, besteht darin, das Skript als Ordneraktion für die Ordner einzurichten, die Sie normalerweise für Fotos verwenden. Dies erfordert zunächst eine sehr geringe Modifikation des obigen AppleScripts, um die entsprechenden Ordneraktionshandler hinzuzufügen, wie folgt:

Fügen Sie oben im Skript hinzu…

on adding folder items to this_folder after receiving added_items
    
    tell application "System Events"
        if my appIsRunning("iTunes") then
            tell process "iTunes"
            …
            …

… und fügen Sie am Ende ein:

    …
    …
    end tell
end adding folder items to

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

Sie müssen das Skript dann in Ihrem ~/Library/Scripts/Folder Action Scripts-Ordner speichern, und Sie sollten dann in der Lage sein, das Skript mit dem entsprechenden Ordner zu verknüpfen, indem Sie mit der rechten Maustaste auf den Ordner im Finder klicken und Dienste, Ordneraktionen einrichten… auswählen.

Beachten Sie, dass Ordneraktionen standardmäßig keine Unterordner umfassen, sodass Sie das Skript mit jedem Ordner verknüpfen müssen, in den Sie regelmäßig Fotos hinzufügen möchten. Darüber hinaus werden die oben genannten Skriptmodifikationen nur initiiert, wenn neue Elemente zu Ihrem Fotos-Ordner hinzugefügt werden; wenn Sie möchten, dass das Skript auch ausgeführt wird, wenn Elemente entfernt werden, müssen Sie eine weitere Kopie des Hauptcodeblocks mit dem Handler on removing folder items from this_folder after losing removed_items hinzufügen. Dies bleibt als Übung für den Leser, oder Sie können einfach eine vollständige Version des Skripts herunterladen, die bereit ist, als Ordneraktion verwendet zu werden.