Apple TV用のiTunesで自動的に写真を更新する

Q: 先週、Apple TVでの写真アルバムの更新に関するあなたの記事を見つけ、私も似たような状況にあります。私はMacユーザーですが、iPhotoを通さずに新しい写真をすぐに追加できるように、Apple TV用にフォルダーを使用することを好みます。また、iMacとiTunesは常にオンにしているので、あなたの記事から得た情報によれば、新しい写真が表示されない理由はそれだと思います。AppleScriptなどを使って、写真フォルダーに何かを追加するたびに共有設定をいじるよりも簡単に自動的に写真を更新する方法はありますか？iTunesをスケジュールに従って自動的に再起動する設定についてのいくつかのヒントを見たことがありますが、私は新しいものを頻繁にダウンロードしたり、Apple TVを使ってiTunesから何かを見たり聞いたりしているので、それはしたくありません。

– パトリック

A: 実際、これはAppleScriptを通じて可能です。これは「GUIスクリプティング」として知られる機能を使用するため、少し手間がかかりますが、目的は達成できます。

残念ながら、iTunesの写真共有機能はAppleScriptに直接公開されていないため、iTunesのコントロールを直接操作する必要があります。AppleScriptがあなたの代わりにこれを行うには、まずOS Xのシステム環境設定アプリケーションに入って、ユニバーサルアクセス設定の下にある支援技術デバイスへのアクセスを有効にするオプションを選択する必要があります。

このオプションにより、AppleScriptはMac上のアプリケーションのユーザーインターフェース要素に直接アクセスできるようになります。これを行った後、以下のようなAppleScriptを使用して、共有する写真を選択ダイアログを開き、いくつかのオプションを変更し、その後そのウィンドウを閉じる手順を経て、iTunesでの写真フォルダーを更新できます。

tell application "System Events"
    if my appIsRunning("iTunes") then
        tell process "iTunes"
            # "高度な"メニューから写真共有設定を開く
            click menu item "共有する写真を選択…" of menu ¬
                "高度な" of menu bar item "高度な" of menu bar 1
            
            # 変更を強制するために「ビデオを含める」チェックボックスの状態を切り替える
            click checkbox "ビデオを含める" of scroll area 1 of window "写真共有設定"
            click button "適用" of window "写真共有設定"
            
            # 元の設定に戻すために「ビデオを含める」チェックボックスの状態を再度切り替える
            click checkbox "ビデオを含める" of scroll area 1 of window "写真共有設定"
            click button "適用" of window "写真共有設定"
            
            # 写真共有設定ウィンドウを閉じる
            click (first button of window "写真共有設定" whose subrole is "AXCloseButton")
        end tell
    end if
end tell

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

上記のスクリプトのインラインコメントは、その動作を説明しています。要約すると、iTunesが実行されていることを確認し、そうであれば単にビデオを含めるオプションを切り替えてiTunesに写真コレクションを再読み込みさせます。ビデオを含めるオプションは、ウィンドウを閉じる前に元の設定に戻すために再度切り替えられます。通常、写真フォルダーにビデオを含めない場合は、この二番目のセクションを削除しても問題ありません。

この場合、iTunesが実行されていない場合、スクリプトは何もしません。なぜなら、iTunesを起動すれば写真フォルダーが更新されるため、スクリプトの残りの部分は冗長になるからです。

スクリプトを使用するには、手動で実行することを選択し、AppleScriptエディタに「アプリケーション」として保存し、デスクトップやDockなどの便利な場所に置いて、クリックすることで実行できます。

または、スクリプトをスケジュールに従って実行するか、写真フォルダーのいずれかに変更を加えたときにトリガーされるフォルダーアクションとして設定することもできます。

スクリプトをスケジュールに従って実行するのは、サードパーティのユーティリティLingon（$3）を使用するのが最も簡単で透明ですが、iCalイベントとして繰り返しスケジュールし、アラートタイプを「スクリプトを実行」に設定することも可能です。

別のアプローチとして、スクリプトを通常使用する写真用のフォルダーに対してフォルダーアクションとして実行するように設定することもできます。これには、上記のAppleScriptに適切なフォルダーアクションハンドラーを追加するための非常にわずかな修正が必要です。

スクリプトの先頭に追加…

on adding folder items to this_folder after receiving added_items
    
    tell application "System Events"
        if my appIsRunning("iTunes") then
        tell process "iTunes"
            …
            …

…そして、最後に挿入します:

    …
    …
    end tell
end adding folder items to

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

次に、スクリプトを~/Library/Scripts/Folder Action Scriptsフォルダーに保存する必要があり、その後Finderでフォルダーを右クリックしてサービス、フォルダーアクションの設定…を選択することで、スクリプトを適切なフォルダーに関連付けることができるようになります。

フォルダーアクションはデフォルトでサブフォルダーを含まないため、定期的に写真を追加する予定の各フォルダーにスクリプトを関連付ける必要があります。さらに、上記のスクリプトの修正は、写真フォルダーに新しいアイテムを追加する際にのみ開始されます。アイテムを削除する際にもスクリプトを実行したい場合は、ハンドラーon removing folder items from this_folder after losing removed_itemsを持つメインコードブロックの別のコピーを追加する必要があります。これは読者の課題として残されており、またはフォルダーアクションとして使用できる完全なバージョンのスクリプトをダウンロードすることもできます。