Atualizando Fotos Automaticamente no iTunes para Apple TV

Q: Encontrei seu artigo na semana passada sobre Atualizando Álbum de Fotos na Apple TV e estou em uma situação semelhante. Sou usuário de Mac, mas prefiro usar pastas para minha Apple TV, pois quero poder adicionar novas fotos rapidamente sem ter que passar pelo iPhoto. Também deixo meu iMac e iTunes ligados o tempo todo, o que, pelo que entendi do seu artigo, é o motivo pelo qual não vejo novas fotos aparecendo. Existe alguma maneira de atualizar automaticamente minhas fotos através do AppleScript ou algo que seja mais fácil do que entrar e mexer nas configurações de compartilhamento sempre que adiciono algo às minhas pastas de fotos? Vi algumas dicas sobre como configurar o iTunes para reiniciar automaticamente em um horário, mas não quero fazer isso porque estou frequentemente baixando novas coisas ou usando a Apple TV para assistir ou ouvir algo do iTunes.

– Patrick

A: Isso é realmente possível via AppleScript; é um pouco complicado, pois usa um recurso conhecido como “GUI Scripting”, que basicamente apenas seleciona as opções normais do iTunes em seu nome, mas funciona.

Infelizmente, nenhum dos recursos de compartilhamento de fotos no iTunes é exposto diretamente ao AppleScript, então somos forçados a manipular os controles do iTunes diretamente. Para permitir que o AppleScript faça isso em seu nome, é primeiro necessário entrar nas Preferências do Sistema do OS X e selecionar a opção Ativar acesso para dispositivos assistivos nas configurações de Acessibilidade Universal.

A opção permite que o AppleScript acesse diretamente os elementos da interface do usuário em aplicativos no seu Mac. Depois de fazer isso, um AppleScript como o seguinte pode ser usado para atualizar suas pastas de fotos no iTunes simplesmente passando pelos passos de abrir a caixa de diálogo Escolher Fotos para Compartilhar, alterando algumas opções e, em seguida, fechando essa janela depois.

tell application "System Events"
    if my appIsRunning("iTunes") then
        tell process "iTunes"
            # Abra as configurações de Compartilhamento de Fotos no menu "Avançado"
            click menu item "Escolher Fotos para Compartilhar..." of menu ¬
                "Avançado" of menu bar item "Avançado" of menu bar 1
            
            # Altere o status da caixa de seleção "Incluir vídeos" para forçar uma mudança
            click checkbox "Incluir vídeos" of scroll area 1 of window "Preferências de Compartilhamento de Fotos"
            click button "Aplicar" of window "Preferências de Compartilhamento de Fotos"
            
            # Altere o status da caixa de seleção "Incluir vídeos" novamente para retornar à configuração original
            click checkbox "Incluir vídeos" of scroll area 1 of window "Preferências de Compartilhamento de Fotos"
            click button "Aplicar" of window "Preferências de Compartilhamento de Fotos"
            
            # Feche a janela de configurações de Compartilhamento de Fotos
            click (first button of window "Preferências de Compartilhamento de Fotos" whose subrole is "AXCloseButton")
        end tell
    end if
end tell

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

Os comentários em linha no script acima descrevem o que ele faz. Para resumir, estamos confirmando que o iTunes está em execução e, se sim, simplesmente alternando a opção Incluir vídeos para forçar o iTunes a reler a coleção de fotos. A opção Incluir vídeos é alternada uma segunda vez para retornar à sua configuração original antes de fechar a janela. Observe que, se você normalmente não inclui vídeos em suas pastas de fotos, pode remover essa segunda seção, pois não importa se a opção Incluir vídeos está ativada ou não.

Se o iTunes não estiver em execução neste caso, o script não faz nada, já que iniciar o iTunes atualizaria as pastas de fotos de qualquer maneira, tornando o restante do script redundante.

Para usar o script, você pode simplesmente optar por executá-lo manualmente, salvando-o no editor de AppleScript como uma “Aplicação” que você pode colocar em um lugar conveniente—como na sua Área de Trabalho ou no seu Dock—e simplesmente executá-lo clicando nele.

Alternativamente, você pode configurar o script para ser executado em uma base programada ou como uma Ação de Pasta que é acionada sempre que você faz uma alteração em uma de suas pastas de fotos.

Configurar seu script para ser executado em um cronograma é mais facilmente e transparentemente feito com o utilitário de terceiros Lingon ($3), no entanto, também é possível agendá-lo como um evento recorrente no iCal com um tipo de alerta “Executar Script”.

Outra maneira de abordar isso é configurar o script para ser executado como uma Ação de Pasta contra quaisquer pastas que você normalmente usa para fotos. Isso requer uma modificação muito leve no AppleScript acima para adicionar os manipuladores de Ação de Pasta apropriados, da seguinte forma:

No topo do script, adicione…

on adding folder items to this_folder after receiving added_items
    
    tell application "System Events"
        if my appIsRunning("iTunes") then
            tell process "iTunes"  
            …
            …

…e na parte inferior, insira:

    …
    …
    end tell
end adding folder items to

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

Você então precisa salvar o script na pasta ~/Library/Scripts/Folder Action Scripts e deve ser capaz de associar o script à pasta apropriada clicando com o botão direito na pasta no Finder e escolhendo Serviços, Configuração de Ações de Pasta…

Observe que as Ações de Pasta não incluem subpastas por padrão, então você precisará associar o script com cada pasta onde planeja adicionar fotos regularmente. Além disso, as modificações do script acima só serão iniciadas ao adicionar novos itens à sua pasta de Fotos; se você quiser que o script também seja executado ao remover itens, precisará adicionar outra cópia do bloco de código principal com o manipulador on removing folder items from this_folder after losing removed_items. Isso é deixado como um exercício para o leitor, ou você pode simplesmente baixar uma versão completa do script pronta para ser usada como uma Ação de Pasta.