Aggiornamento automatico delle foto in iTunes per Apple TV

Q: Ho trovato il tuo articolo la settimana scorsa su Come aggiornare gli album fotografici su Apple TV e mi trovo in una situazione simile. Sono un utente Mac, ma preferisco usare le cartelle per la mia Apple TV poiché voglio poter aggiungere rapidamente nuove immagini senza dover passare attraverso iPhoto. Lascio anche il mio iMac e iTunes accesi tutto il tempo, il che, da quanto ho capito dal tuo articolo, è il motivo per cui non vedo le nuove foto apparire. C’è un modo per aggiornare automaticamente le mie foto tramite AppleScript o qualcosa che sarebbe più facile che entrare e modificare le impostazioni di condivisione ogni volta che aggiungo qualcosa alle mie cartelle fotografiche? Ho visto alcuni suggerimenti su come impostare iTunes per riavviarsi automaticamente secondo un programma, ma non voglio farlo perché spesso scarico nuove cose o uso Apple TV per guardare o ascoltare qualcosa da iTunes.

– Patrick

A: Questo è effettivamente possibile tramite AppleScript; è un po’ complicato poiché utilizza una funzione nota come “GUI Scripting” che fondamentalmente seleziona le normali opzioni di iTunes per tuo conto, ma fa il suo lavoro.

Sfortunatamente, nessuna delle funzionalità di condivisione foto in iTunes è esposta direttamente ad AppleScript, quindi siamo costretti a manipolare direttamente i controlli di iTunes. Per consentire ad AppleScript di fare questo per tuo conto, è prima necessario andare nell’applicazione Preferenze di Sistema di OS X e selezionare l’opzione Abilita accesso per dispositivi assistivi sotto le impostazioni di Accessibilità Universale.

L’opzione consente ad AppleScript di accedere direttamente agli elementi dell’interfaccia utente nelle applicazioni sul tuo Mac. Una volta fatto questo, un AppleScript come il seguente può essere utilizzato per aggiornare le tue cartelle fotografiche in iTunes semplicemente seguendo i passaggi per aprire la finestra di dialogo Scegli foto da condividere, modificare alcune opzioni e poi chiudere quella finestra successivamente.

tell application "System Events"
    if my appIsRunning("iTunes") then
        tell process "iTunes"
            # Apri le impostazioni di condivisione foto dal menu "Avanzate"
            click menu item "Scegli foto da condividere…" of menu ¬
                "Avanzate" of menu bar item "Avanzate" of menu bar 1
            
            # Attiva lo stato della casella di controllo "Includi video" per forzare un cambiamento
            click checkbox "Includi video" of scroll area 1 of window "Preferenze condivisione foto"
            click button "Applica" of window "Preferenze condivisione foto"
            
            # Attiva di nuovo lo stato della casella di controllo "Includi video" per riportarlo alla sua impostazione originale
            click checkbox "Includi video" of scroll area 1 of window "Preferenze condivisione foto"
            click button "Applica" of window "Preferenze condivisione foto"
            
            # Chiudi la finestra delle impostazioni di condivisione foto
            click (first button of window "Preferenze condivisione foto" whose subrole is "AXCloseButton")
        end tell
    end if
end tell

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

I commenti in linea nello script sopra descrivono cosa fa. In sintesi, stiamo confermando che iTunes è in esecuzione e, se sì, semplicemente attiviamo l’opzione Includi video per forzare iTunes a rileggere la collezione fotografica. L’opzione Includi video viene attivata una seconda volta per riportarla alla sua impostazione originale prima di chiudere la finestra. Nota che se normalmente non includi video nelle tue cartelle fotografiche, puoi rimuovere questa seconda sezione poiché non importa se l’opzione Includi video è impostata o meno.

Se iTunes non è in esecuzione in questo caso, lo script non fa nulla, poiché avviare iTunes aggiornerebbe comunque le cartelle fotografiche, rendendo effettivamente il resto dello script ridondante.

Per utilizzare lo script, puoi semplicemente scegliere di eseguirlo manualmente, salvandolo nell’editor AppleScript come un “Applicazione” che puoi poi mettere in un luogo comodo—come sul tuo Desktop o nel tuo Dock—e semplicemente eseguirlo facendo clic su di esso.

In alternativa, potresti impostare lo script per essere eseguito sia su base programmata che come un’azione di cartella che viene attivata ogni volta che apporti una modifica a una delle tue cartelle fotografiche.

Impostare il tuo script per essere eseguito secondo un programma è più facilmente e trasparentemente fatto con l’utilità di terze parti Lingon ($3), tuttavia è anche possibile programmarlo come un evento iCal ricorrente con un tipo di avviso “Esegui script”.

Un altro modo per affrontare questo è impostare lo script per essere eseguito come un Azione di Cartella contro le cartelle che normalmente usi per le foto. Questo richiede prima una leggera modifica allo script AppleScript sopra per aggiungere i gestori di azione di cartella appropriati, come segue:

In cima allo script, aggiungi…

on adding folder items to this_folder after receiving added_items
    
    tell application "System Events"
        if my appIsRunning("iTunes") then
            tell process "iTunes"
            …
            …

…e in fondo, inserisci:

    …
    …
    end tell
end adding folder items to

on appIsRunning(appname)
    tell application "System Events" to (name of processes) contains appname
end appIsRunning

Devi quindi salvare lo script nella tua cartella ~/Library/Scripts/Folder Action Scripts e dovresti poi essere in grado di associare lo script con la cartella appropriata facendo clic destro sulla cartella nel Finder e scegliendo Servizi, Impostazione Azioni di Cartella…

Nota che le azioni di cartella non includono sottocartelle per impostazione predefinita, quindi dovrai associare lo script con ciascuna cartella in cui prevedi di aggiungere foto regolarmente. Inoltre, le modifiche allo script sopra verranno avviate solo quando aggiungi nuovi elementi alla tua cartella Foto; se desideri che lo script venga eseguito anche quando rimuovi elementi, dovrai aggiungere un’altra copia del blocco di codice principale con il gestore on removing folder items from this_folder after losing removed_items. Questo è lasciato come esercizio per il lettore, oppure puoi semplicemente scaricare una versione completa dello script pronta per essere utilizzata come azione di cartella.